home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 005 / miscstat.arc / STUTDSTT.BAS < prev   
Encoding:
BASIC Source File  |  1986-04-25  |  1.8 KB  |  59 lines
  1. 1 'STUdent's T-DiSTribution Test
  2. 2 KEY OFF:SCREEN 0,1,0:WIDTH 40:COLOR 15,1,9:CLS
  3. 10  PRINT "STUDENT'S T-DISTRIBUTION TEST"
  4. 20  PRINT 
  5. 30  DIM P(10,2)
  6. 40  DIM V(2),R(2),M(2),D(2)
  7. 50  PRINT "TEST 1: MEAN=X"
  8. 60  PRINT "TEST 2: MEAN=MEAN, STANDARD DEVIATION=
  9. 62  PRINT "                   STANDARD DEVIATION
  10. 70  PRINT "TEST 3: MEAN=MEAN, STANDARD DEVIATION<>
  11. 72  PRINT "                   STANDARD DEVIATION
  12. 80  PRINT:PRINT "WHICH HYPOTHESIS: ";:LOCATE ,,1:T=0
  13. 90  K$=INKEY$:IF K$="" THEN 90
  14. 91  IF K$=CHR$(13) AND T THEN PRINT:GOTO 100
  15. 92  IF K$=CHR$(27) THEN 450
  16. 94  IF K$<"1" OR K$>"3" THEN 90
  17. 96  T=VAL(K$):PRINT K$;:GOTO 90
  18. 100  PRINT 
  19. 110  FOR I = 1 TO  SGN (T - 1) + 1
  20. 120 V(I) = 0
  21. 130 D(I) = 0
  22. 140  PRINT "SAMPLE";I;":"
  23. 150  PRINT "  NUMBER OF ELEMENTS";
  24. 160  INPUT R(I)
  25. 170  FOR J = 1 TO R(I)
  26. 180  PRINT "   ELEMENT"J;
  27. 190  INPUT P(J,I)
  28. 200 V(I) = V(I) + P(J,I)
  29. 210 D(I) = D(I) + P(J,I) ^ 2
  30. 220  NEXT J
  31. 230 M(I) = V(I) / R(I)
  32. 240 V(I) = (D(I) - V(I) ^ 2 / R(I)) / (R(I) - 1)
  33. 250  NEXT I
  34. 260  PRINT 
  35. 270  IF T = 2 THEN 340
  36. 280  IF T = 3 THEN 380
  37. 290  PRINT "VALUE OF MEAN";
  38. 300  INPUT M
  39. 310 A = (M(1) - M) *  SQR (R(1) / V(1))
  40. 320 B = R(1) - 1
  41. 330  GOTO 420
  42. 340 A = (M(1) - M(2)) /  SQR (1 / R(1) + 1 / R(2))
  43. 350 B = R(1) + R(2) - 2
  44. 360 A = A /  SQR (((R(1) - 1) * V(1) + (R(2) - 1) * V(2)) / B)
  45. 370  GOTO 420
  46. 380 A = (M(1) - M(2)) /  SQR (V(1) / R(1) + V(2) / R(2))
  47. 390 B = (V(1) / R(1) + V(2) / R(2)) ^ 2
  48. 400 B = B / ((V(1) / R(1)) ^ 2 / (R(1) + 1) + (V(2) / R(2)) ^ 2 / (R(2) + 1)) - 2
  49. 410 B =  INT (B + .5)
  50. 420  PRINT 
  51. 430  PRINT "T-VALUE: " ABS (A)
  52. 440  PRINT "DEGREES OF FREEDOM: "B
  53. 450 PRINT:LOCATE 24,1:PRINT"PRESS <SPACE> TO RUN AGAIN";
  54. 460 LOCATE 25,1:PRINT"PRESS <ESC> TO EXIT";
  55. 470 K$=INKEY$:IF K$="" THEN 470
  56. 480 IF K$=" " THEN RUN
  57. 490 IF K$<>CHR$(27) THEN 470
  58. 10000 RUN"MENU
  59.